$TITLE: M11-1.GMS: steady state capital stock, comparative steady-states


$ONTEXT
 "closure rule": instead of the capital stock being fixed
 (quantity closure), the stock
 adjusts to satisfy the steady-state relationship between the rental
 rate and the price of producing new capital (price closure):
   delta = depreciation rate
   rho   = rate of time preference

 rental rate = (1 - (1 - delta)/(1 + rho))*(price of new capital)

 this is done via a subsidy to capital use that creates the wedge
   subsidy = (1 - delta)/(1 + rho)

 KFORWARD is (undepreciated) capital taken forward from previous
   period and K is new capital production, which can be used instantly.

 The steady-state condition is depreciation equal new capital formation
  (KFORWARD + K)*DELTA = K   or   KFOWARD = K*(1-DELTA)/DELTA





                Production Sectors          Consumers

   Markets   |    X       Y    K     W    |       CONS
   ------------------------------------------------------
        PX   |   100               -100    |
        PY   |          100        -100    |
        PW   |                      200    |       -200
        PL   |  - 40     -60  -60          |        160
        PK   |  -120     -80   60          |        140
        SUB  |    60      40               |       -100
   ------------------------------------------------------
$OFFTEXT

PARAMETERS
   RHO          Time preference parameter
   DELTA        Depreciation rate
   TAU          Effective capital use subsidy
   KTAX         Tax on new capital production
   NEWCAP       New capital stock after counterfactual (= 1 initially);

RHO     = 0.4;
DELTA   = 0.3;
TAU     = - (1 - DELTA)/(1 + RHO);
KTAX    = 0;

NONNEGATIVE VARIABLES
   X       Activity level for sector X
   Y       Activity level for sector Y
   W       Activity level for sector W (Hicksian welfare index)
   K       Capital stock index

   PX      Price index for commodity X
   PY      Price index for commodity Y
   PL      Price index for primary factor L
   PK      Price index for primary factor K
   PW      Price index for welfare (expenditure function)

   CONS    Income definition for CONS
   KFORWRD Capital stock from previous period;

EQUATIONS
   PRF_X   Zero profit for sector X
   PRF_Y   Zero profit for sector Y
   PRF_W   Zero profit for sector W (Hicksian welfare index)
   PRF_K   Zero profit for capital index

   MKT_X   Supply-demand balance for commodity X
   MKT_Y   Supply-demand balance for commodity Y
   MKT_L   Supply-demand balance for primary factor L
   MKT_K   Supply-demand balance for factor K
   MKT_W   Supply-demand balance for aggregate demand

   I_CONS  Income definition for CONS
   A_KFORWRD  Auxiliary equation to determine the carry forward;

*       Zero profit conditions:

PRF_X..    100 * PL**0.4 * (PK*(1+TAU)/0.5)**0.6 =G= 100 * PX;

PRF_Y..    100 * PL**0.6 * (PK*(1+TAU)/0.5)**0.4 =G= 100 * PY;

PRF_W..    200 * PX**0.5 * PY**0.5 =G= 200 * PW;

PRF_K..    60*PL =G= 60 * PK * (1-KTAX);

*       Market clearing conditions:

MKT_X..    100 * X =G= 100 * W * PW/PX;

MKT_Y..    100 * Y =G= 100 * W * PW/PY;

MKT_W..    200 * W =G= CONS / PW;

MKT_L..    160  =G= 60*K + 40* X*PX/PL + 60*Y*PY/PL;

MKT_K..    140*KFORWRD + 60*K =G= 120 * X * PX*0.5/(PK*(1+TAU)) +
                                   80 * Y * PY*0.5/(PK*(1+TAU));

*       Income constraints:

I_CONS..   CONS =E= 160 * PL + 140*KFORWRD *PK +
                   PK * TAU * (120 * X * PX*0.5/(PK*(1+TAU)) +
                                80 * Y * PY*0.5/(PK*(1+TAU))) +
                                60* PK * KTAX * K;

*       Auxiliary constraints:

A_KFORWRD.. 140*KFORWRD  =E= 60*K * (1-DELTA) / DELTA;

MODEL ALGEBRAIC /PRF_X.X, PRF_Y.Y, PRF_W.W, PRF_K.K,
                 MKT_X.PX, MKT_Y.PY, MKT_L.PL, MKT_K.PK, MKT_W.PW,
                 I_CONS.CONS, A_KFORWRD.KFORWRD/;

X.L     =1;
Y.L     =1;
W.L     =1;
K.L     =1;

PX.L    =1;
PY.L    =1;
PK.L    =1;
PW.FX   =1;
PL.L    =1;

CONS.L  =200;

KFORWRD.L = 1;

ALGEBRAIC.ITERLIM = 0;
SOLVE ALGEBRAIC USING MCP;
ALGEBRAIC.ITERLIM = 2000;
SOLVE ALGEBRAIC USING MCP;

*  Raise the rate of time preference from 0.4 to 0.6:

RHO  = 0.6;
TAU  = - (1 - DELTA)/(1 + RHO);

SOLVE ALGEBRAIC USING MCP;

NEWCAP = K.L;
DISPLAY NEWCAP;

*  Set rho back to 0.4, tax new capital at 0.20

RHO  = 0.4;
TAU  = - (1 - DELTA)/(1 + RHO);

KTAX = 0.20;

SOLVE ALGEBRAIC USING MCP;

NEWCAP = K.L;
DISPLAY NEWCAP;