$TITLE  TWOHOUSE.GMS: two households with different preferences
*                 and different endowments endowments

$ONTEXT
Two household: differ in preferences and in endowments
Household A: well endowed with labor,
  preference for labor-int good Y
Household B: well endowed with capital,
  preference for capital-int good X
Allows for tax to be redistributed unevenly between households

                  Production Sectors               Consumers
   Markets   |    X       Y      WA      WB  |     A      B
   ----------------------------------------------------------
        PX   |  100             -40     -60  |
        PY   |          100     -60     -40  |
        PWA  |                  100          |  -100
        PWB  |                          100  |          -100
        PL   |  -25     -75                  |    90      10
        PK   |  -75     -25                  |    10      90
   ----------------------------------------------------------

The tax redistribution or sharing rule can also be interpreted
as the relative number of households in each group, with all
households getting an equal share of tax receipts
$OFFTEXT

PARAMETERS
   TX      Ad-valorem tax rate for X sector inputs
   SHA     Share of tax revenue given back to household A
   SHB     share of tax revenue given back to household B;

TX  = 0;
SHA = 0.5;
SHB = 0.5;

NONNEGATIVE VARIABLES

    X       Activity level for sector X
    Y       Activity level for sector Y
    WA      Activity level for sector WA
    WB      Activity level for sector WB
    PX      Price index for commodity X
    PY      Price index for commodity Y
    PK      Price index for primary factor K
    PL      Price index for primary factor L
    PWA     Price index for welfare A(expenditure function)
    PWB     Price index for welfare B(expenditure function)

    CONSA   Income definition for CONSA
    CONSB   Income definition for CONSB;

EQUATIONS

    PRF_X   Zero profit for sector X
    PRF_Y   Zero profit for sector Y
    PRF_WA  Zero profit for sector WA
    PRF_WB  Zero profit for sector WB

    MKT_X   Supply-demand balance for commodity X
    MKT_Y   Supply-demand balance for commodity Y
    MKT_L   Supply-demand balance for primary factor L
    MKT_K   Supply-demand balance for primary factor K
    MKT_WA  Supply-demand balance for consumer A
    MKT_WB  Supply-demand balance for consumer B

    I_CONSA Income definition for CONSA
    I_CONSB Income definition for CONSB;

*       Zero profit conditions:

PRF_X..      100*(PL**0.25 * PK**0.75) * (1+TX) =G= 100*PX;

PRF_Y..      100*(PL**0.75 * PK**0.25) =G= 100*PY;

PRF_WA..     100*(PX**0.4 * PY**0.6) =G= 100*PWA;

PRF_WB..     100*(PX**0.6 * PY**0.4) =G= 100*PWB;

*       Market clearing conditions:

MKT_X..      100*X =G= 40*WA*PWA/PX + 60*WB*PWB/PX;

MKT_Y..      100*Y =G= 60*WA*PWA/PY + 40*WB*PWB/PY;

MKT_WA..     100*WA =G= CONSA/PWA;

MKT_WB..     100*WB =G= CONSB/PWB;

MKT_L..      90 + 10 =G= 25*X*(PX/(1+TX))/PL + 75*Y*PY/PL;

MKT_K..      10 + 90 =G= 75*X*(PX/(1+TX))/PK + 25*Y*PY/PK;

*       Income constraints:

I_CONSA..    CONSA =E= 90*PL + 10*PK + SHA*TX*100*X*PX/(1+TX);

I_CONSB..    CONSB =E= 10*PL + 90*PK + SHB*TX*100*X*PX/(1+TX);

MODEL TWOHOUSE /PRF_X.X, PRF_Y.Y, PRF_WA.WA, PRF_WB.WB,
                 MKT_X.PX, MKT_Y.PY, MKT_L.PL,
                 MKT_K.PK, MKT_WA.PWA, MKT_WB.PWB,
                 I_CONSA.CONSA, I_CONSB.CONSB /;

*       Check the benchmark:

X.L     =1;
Y.L     =1;
WA.L    =1;
WB.L    =1;

PL.FX   =1;
PX.L    =1;
PY.L    =1;
PK.L    =1;
PWA.L   =1;
PWB.L   =1;

CONSA.L =100;
CONSB.L =100;

TX      =0;

TWOHOUSE.ITERLIM = 0;
SOLVE TWOHOUSE USING MCP;
TWOHOUSE.ITERLIM = 1000;
SOLVE TWOHOUSE USING MCP;

TX   = 0.50;
SOLVE TWOHOUSE USING MCP;

* counterfactual: give a larger share of tax to household B
* illustrates impossibility of making both types better off

TX   = 0.50;
SHA  = 0.25;
SHB  = 0.75;

SOLVE TWOHOUSE USING MCP;

* suppose that 80% of households are type A, 20% type B
* and all individual households get an equal share
* of tax receipts

TX   = 0.50;
SHA  = 0.80;
SHB  = 0.20;

SOLVE TWOHOUSE USING MCP;