* M0B.GMS introductory model using MCP
* (general equilibrium)

PARAMETERS
 LBAR    labor supply (fixed and inelastic)
 ALPHA   productivity parameter  X = ALPHA*L;

LBAR = 100;
ALPHA = 2;

POSITIVE VARIABLES
 P        price of X
 X        quantity of X
 W        wage rate
 INCOME   income from labor supply;

EQUATIONS
 ZPROFIT        zeroprofits in X production
 CMKTCLEAR      commodity (X) market clearing
 LMKTCLEAR      labor market clearing
 CONSINCOME     consumer income;

ZPROFIT..    W/ALPHA =G= P;
CMKTCLEAR..  X =G= INCOME/P;
LMKTCLEAR..  LBAR =G= X/ALPHA;
CONSINCOME.. INCOME =G= W*LBAR;

MODEL GE /ZPROFIT.X, CMKTCLEAR.P, LMKTCLEAR.W, CONSINCOME.INCOME/;

* set some starting values
P.L = 1;
W.L = 1;
X.L = 200;
INCOME.L = 100;

* choose a numeraire
W.FX = 1;

OPTION MCP = PATH;
SOLVE GE USING MCP;

* double labor productivity
ALPHA = 4;
SOLVE GE USING MCP;

* change numeraire
W.UP = + INF;
W.LO = 0;
P.FX = 1;

ALPHA = 2;
SOLVE GE USING MCP;

* double labor productivity
ALPHA   =   4;
SOLVE   GE   USING  MCP;