$TITLE  Model M1_MCP: Closed 2x2 Economy --  An Introduction to the Basics

$ONTEXT

This is the exact same model as M1_MPS.GMS but uses the MCP format.

                  Production Sectors          Consumers
   Markets   |    X       Y        W    |       CONS
   ------------------------------------------------------
        PX   |  100             -100    |
        PY   |          100     -100    |
        PW   |                   200    |       -200
        PL   |  -25     -75             |        100
        PK   |  -75     -25             |        100
   ------------------------------------------------------

$OFFTEXT


PARAMETERS

 TX         Ad-valorem tax rate for X sector inputs
 LENDOW     Labor endowment multiplier;

TX = 0;
LENDOW = 1;

POSITIVE VARIABLES
 X
 Y
 W
 PX
 PY
 PW
 PL
 PK
 CONS;

EQUATIONS
 PRF_X   Zero profit for sector X
 PRF_Y   Zero profit for sector Y
 PRF_W   Zero profit for sector W (Hicksian welfare index)

 MKT_X   Supply-demand balance for commodity X
 MKT_Y   Supply-demand balance for commodity Y
 MKT_L   Supply-demand balance for primary factor L
 MKT_K   Supply-demand balance for primary factor L
 MKT_W   Supply-demand balance for aggregate demand

 I_CONS  Income definition for CONS;


*       Zero profit inequalities

PRF_X..         100 * PL**0.25 * PK**0.75 * (1+TX) =G= 100*PX;

PRF_Y..         100 * PL**0.75* PK**0.25 =G= 100*PY;

PRF_W..         200 * PX**0.5 * PY**0.5 =G= 200*PW;

*       Market clearance inequalities

MKT_X..         100 * X =G= 100 * W * PX**0.5 * PY**0.5 / PX;

MKT_Y..         100 * Y =G= 100 * W * PX**0.5 * PY**0.5 / PY;

MKT_W..         200 * W =E= CONS / PW;

MKT_L..         100 * LENDOW =G= 25 * X * PL**0.25 * PK**0.75 / PL +
                                 75 * Y * PL**0.75 * PK**0.25 / PL;

MKT_K..         100 =G= 75 * X * PL**0.25 * PK**0.75 / PK +
                        25 * Y * PL**0.75 * PK**0.25 / PK;

*       Income balance equations

I_CONS..        CONS =E= 100*LENDOW*PL + 100*PK + TX*100*X*PL**0.25*PK**0.75;


MODEL ALGEBRAIC /PRF_X.X, PRF_Y.Y, PRF_W.W, MKT_X.PX, MKT_Y.PY, MKT_L.PL, 
                 MKT_K.PK, MKT_W.PW, I_CONS.CONS /;


*       Chose a numeraire (not necessary)

PW.FX = 1;

*       Set initial values of variables:

X.L=1; Y.L=1; W.L=1; PX.L=1; PY.L=1; PK.L=1; PL.L=1;
CONS.L=200;

SOLVE ALGEBRAIC USING MCP;


*       Solve the counterfactuals:

TX = 0.5;       
LENDOW = 1;
SOLVE ALGEBRAIC USING MCP;

TX = 0;         
LENDOW = 2;
SOLVE ALGEBRAIC USING MCP;