$TITLE  Model M1_MPS: Closed 2x2 Economy --  An Introduction to the Basics

$ONTEXT

This is the exact same model as M1_MCP.GMS but uses the MPS/GE format.


                  Production Sectors          Consumers
   Markets   |    X       Y        W    |       CONS
   ------------------------------------------------------
        PX   |  100             -100    |
        PY   |          100     -100    |
        PW   |                   200    |       -200
        PL   |  -25     -75             |        100
        PK   |  -75     -25             |        100
   ------------------------------------------------------

$OFFTEXT


PARAMETERS
  TX         Ad-valorem tax rate for X sector inputs
  LENDOW     Labor endowment multiplier;

TX = 0;
LENDOW = 1;

$ONTEXT

$MODEL:M1_MPS

$SECTORS:
        X       ! Activity level for sector X
        Y       ! Activity level for sector Y
        W       ! Activity level for sector W (Hicksian welfare index)

$COMMODITIES:
        PX      ! Price index for commodity X
        PY      ! Price index for commodity Y
        PL      ! Price index for primary factor L
        PK      ! Price index for primary factor K
        PW      ! Price index for welfare (expenditure function)

$CONSUMERS:
        CONS    ! Income level for consumer CONS

$PROD:X s:1
        O:PX  Q:100
        I:PL  Q:25 A:CONS T:TX
        I:PK  Q:75 A:CONS T:TX

$PROD:Y s:1
        O:PY  Q:100
        I:PL  Q:75
        I:PK  Q:25

$PROD:W s:1
        O:PW   Q:200
        I:PX   Q:100
        I:PY   Q:100

$DEMAND:CONS
        D:PW   Q:200
        E:PL   Q:(100*LENDOW)
        E:PK   Q:100

$OFFTEXT

$SYSINCLUDE mpsgeset M1_MPS

PW.FX = 1;

$INCLUDE M1_MPS.GEN
SOLVE M1_MPS USING MCP;


*       Solve the counterfactuals

TX = 0.5;       
LENDOW = 1;

$INCLUDE M1_MPS.GEN
SOLVE M1_MPS USING MCP;

TX = 0;         
LENDOW = 2;

$INCLUDE M1_MPS.GEN
SOLVE M1_MPS USING MCP;