$TITLE  Model M25: Closed 2x2 Economy with an Unprofitable Activity

$ONTEXT

                  Production Sectors          Consumers
   Markets   |    X       Y        W    |       CONS
   ------------------------------------------------------
        PX   |  100             -100    |
        PY   |          100     -100    |
        PW   |                   200    |       -200
        PL   |  -40     -60             |        100
        PK   |  -60     -40             |        100
   ------------------------------------------------------

Activity Z is unprofitable at initial equilibrium prices.  It is
therefore not operated, and we cannot infer its technical properties
from the benchmark social accounting data. We assume that Z is 10% 
less efficient than X.

$OFFTEXT

PARAMETERS
 TX;

TX = 0;

$ONTEXT
$MODEL:M25

$SECTORS:
        X       ! Activity level for sector X
        Y       ! Activity level for sector Y
        W       ! Activity level for sector W (Hicksian welfare index)
        Z       ! Alternative activity for producing X.

$COMMODITIES:
        PX      ! Price index for commodity X
        PY      ! Price index for commodity Y
        PL      ! Price index for primary factor L
        PK      ! Price index for primary factor K
        PW      ! Price index for welfare (expenditure function)

$CONSUMERS:
        CONS    ! Income level for consumer CONS

$PROD:X s:1
        O:PX   Q:100
        I:PL   Q: 40  A:CONS T:TX
        I:PK   Q: 60  A:CONS T:TX

$PROD:Y s:1
        O:PY  Q:100
        I:PL   Q:60
        I:PK   Q:40

$PROD:Z s:1
        O:PX    Q: 100
        I:PL    Q:  44
        I:PK    Q:  66

$PROD:W s:1
        O:PW    Q:200
        I:PX    Q:100
        I:PY    Q:100

$DEMAND:CONS
        D:PW    Q:200
        E:PL    Q:100
        E:PK    Q:100

$OFFTEXT
$SYSINCLUDE mpsgeset M25

PW.FX = 1;

Z.L = 0;

$INCLUDE M25.GEN
SOLVE M25 USINCP MCP;

*       Lets levy a high on sector X and see what happens:

TX = 0.25;
$INCLUDE M25.GEN
SOLVE M25 USING MCP;

*       What is the effect of the tax if Z could not be used?

Z.FX = 0;

TX = 0.25;
$INCLUDE M25.GEN
SOLVE M25 USING MCP;