$TITLE: Model M62-MPS: Large-Group Monopolistic Competition, uses MPS/GE
* alternative iterative formulation

$ONTEXT

                        Production Sectors           Consumers
   Markets   |   XI     X        N        Y        W    |  CONS   ENTR
   ----------------------------------------------------------------------
        PX   |        100                       -100    |
        CX   !  100  -100                               |
        PY   |                          100     -100    |
        PF   |                  20                      |          -20
        PU   |                                   200    |  -200
        PW   |  -32             -8      -60             |   100
        PZ   |  -48            -12      -40             |   100
        MK   |  -20                                     |           20


$OFFTEXT

SETS I /1*40/;

PARAMETERS
  ENDOW  Size index for the economy
  INDEX  Price index for the X goods
  EP     Elasticity of substitution among X varieties
  EXT    Externality scaling parameter
  FN     Scaling parameter to capture externality effect
  MK     Markup expressed as proportion of marginal cost;

ENDOW = 1;
EP = 5;
EXT = 1/(EP - 1);
MK = 1/(EP - 1);
FN = 1;

$ONTEXT

$MODEL:M62

$SECTORS:
        X       ! Activity level for sector X
        Y       ! Activity level for sector Y
        W       ! Activity level for sector W (Hicksian welfare index)
        N       ! Activity level -- sector X fixed costs = number of firms

$COMMODITIES:
        PX      ! Price index for commodity X (gross of markup)
        PY      ! Price index for commodity Y
        PW      ! Price index for unskilled labor
        PZ      ! Price index for skilled labor
        PF      ! Unit price of inputs to fixed cost
        PU      ! Price index for welfare (expenditure function)

$CONSUMERS:
        CONS    ! Income level for consumer CONS
        ENTRE   ! Entrepreneur (converts markup revenue to fixed cost)


$PROD:X s:1
        O:PX    Q:(80*FN**EXT)
        I:PW    Q: 32  A:ENTRE  T:MK
        I:PZ    Q: 48  A:ENTRE  T:MK

$PROD:Y s:1
        O:PY    Q:100
        I:PW    Q: 60
        I:PZ    Q: 40

$PROD:N s:1
        O:PF    Q:20
        I:PZ    Q:12
        I:PW    Q: 8

$PROD:W s:1.0
        O:PU    Q:200
        I:PX    Q: 80   P:1.25
        I:PY    Q:100

$DEMAND:CONS
        D:PU    Q:200
        E:PW    Q:(100*ENDOW)
        E:PZ    Q:(100*ENDOW)

$DEMAND: ENTRE
        D:PF    Q:20

$OFFTEXT
$SYSINCLUDE mpsgeset M62

*       Benchmark replication:
PY.FX = 1;
PX.L = 1.25;
N.L = 1;
FN = 1;

$INCLUDE M62.GEN
SOLVE M62 USING MCP

LOOP(I$(ABS(FN-N.L) GT 0.0001),

FN = MAX(N.L, 0.0001);

*OPTION SOLPRINT = OFF;
$INCLUDE M62.GEN
SOLVE M62 USING MCP

);

DISPLAY N.L, FN;


ENDOW = 2;

$INCLUDE M62.GEN
SOLVE M62 USING MCP

LOOP(I$(ABS(FN-N.L) GT 0.0001),

FN = MAX(N.L, 0.0001);

*OPTION SOLPRINT = OFF;
$INCLUDE M62.GEN
SOLVE M62 USING MCP

);

DISPLAY N.L, FN;




$EXIT
IF(ORD(I) EQ CARD(I), OPTION SOLPRINT = ON;
ELSE OPTION SOLPRINT = OFF; );