$TITLE  Model M31: Closed economy 2x2 with taxes in the benchmark

SCALAR  TX      Proportional output tax on sector X,
        TY      Proportional output tax on sector Y,
        TLX     Ad-valorem tax on labor inputs to X,
        TKX     Ad-valorem tax on capital inputs to X;

POSITIVE VARIABLES

        X       ! Activity level for sector X,
        Y       ! Activity level for sector Y,
        W       ! Activity level for sector W (Hicksian welfare index),
        PX      ! Price index for commodity X,
        PY      ! Price index for commodity Y,
        PL      ! Price index for primary factor L,
        PK      ! Price index for primary factor K,
        PW      ! Price index for welfare (expenditure function),
	CONS	! Income definition for CONS;

EQUATIONS

        PRF_X   Zero profit for sector X
        PRF_Y   Zero profit for sector Y
        PRF_W   Zero profit for sector W (Hicksian welfare index)

        MKT_X   Supply-demand balance for commodity X
        MKT_Y   Supply-demand balance for commodity Y
        MKT_L   Supply-demand balance for primary factor L
        MKT_K   Supply-demand balance for primary factor L
        MKT_W   Supply-demand balance for aggregate demand

        I_CONS  Income definition for CONS;

*	Zero profit conditions:

PRF_X..		100 * ( (1+TLX)*PL/2 )**0.4 * ( PK * (1+TKX) ) **0.6 =G= 100 * PX*(1-TX);

PRF_Y..		100 * PL**0.6 * PK**0.4 =G= 100 * PY * (1-TY);

PRF_W..		200 * PX**0.5 * PY**0.5 =G= 200 * PW;

*	Market clearing conditions:

MKT_X..		100 * X =G= 100 * W * PW / PX;

MKT_Y..		100 * Y =G= 100 * W * PW / PY;

MKT_W..		200 * W =G= CONS / PW;

MKT_L..		80  =G= 20 * X * PX*(1-TX) * 2 /(PL*(1+TLX)) + 60 * Y * PY * (1-TY)/PL;

MKT_K..		100 =G= 60 * X * PX*(1-TX) /(PK*(1+TKX)) + 40 * Y * PY * (1-TY)/PK; 

*	Income constraints:

I_CONS..	CONS =E= 80 * PL + 100 * PK +  100 * W * PW * TX + 
			TLX * PL * 20 * X * PX * (1-TX)*2/(PL*(1+TLX)) + 
			TKX * PK * 60 * X * PX * (1-TX)/(PK*(1+TKX)) + 
			100 * W * PW * TY ;  

MODEL ALGEBRAIC /PRF_X.X, PRF_Y.Y, PRF_W.W, MKT_X.PX, MKT_Y.PY, MKT_L.PL, 
                 MKT_K.PK, MKT_W.PW, I_CONS.CONS /;

X.L	=1;
Y.L	=1;
W.L	=1;

PL.L	=1;
PX.L	=1;
PY.L	=1;
PK.L	=1;
PW.FX	=1;

CONS.L	=200;

TX	=0;
TY	=0;
TLX	=1;
TKX	=0;

ALGEBRAIC.ITERLIM = 0;

SOLVE ALGEBRAIC USING MCP;

*       In the first counterfactual, we replace the tax on labor inputs
*       by a uniform tax on both factors:

TLX = 0.25;  
TKX = 0.25;
TX  = 0;
TY  = 0;

ALGEBRAIC.ITERLIM = 2000;

SOLVE ALGEBRAIC USING MCP;

*       Now demonstrate that a 25% tax on all inputs is equivalent to a
*       20% tax on the output (or all outputs if more than one)

TLX = 0;
TKX = 0;
TX  = 0.2;
TY  = 0;

SOLVE ALGEBRAIC USING MCP;

*       Finally, demonstrate that a 20% tax on the X sector output is 
*       equivalent to a 25% subsidy on Y sector output (assumes that the
*       funds for the subsidy can be raised lump sum from the consumer!)

TKX = 0;
TLX = 0;
TX = 0;
TY = -0.25;

SOLVE ALGEBRAIC USING MCP;