$TITLE Model M10-2: TWOxTWOxONE economy -- MPS/GE version of model M3-4b

$ONTEXT

This is the exact same model as M3-4b.GMS but uses the MPS/GE format.


                  Production Sectors          Consumers
   Markets   |    X       Y        W    |       CONS
   ------------------------------------------------------
        PX   |  100             -100    |
        PY   |          100     -100    |
        PW   |                   200    |       -200
        PL   |  -25     -75             |        100
        PK   |  -75     -25             |        100
   ------------------------------------------------------

$OFFTEXT


PARAMETERS

 TX         ad-valorem tax rate for X sector inputs
 TY         ad-valorem tax rate for Y sector inputs
 LENDOW     labor endowment multiplier
 KENDOW     capital endowment multiplier;

TX = 0; TY = 0;
LENDOW = 1;
KENDOW = 1;


$ONTEXT

$MODEL:M10_2

$SECTORS:
        X       ! Activity level for sector X
        Y       ! Activity level for sector Y
        W       ! Activity level for sector W (Hicksian welfare index)

$COMMODITIES:
        PX      ! Price index for commodity X
        PY      ! Price index for commodity Y
        PL      ! Price index for primary factor L
        PK      ! Price index for primary factor K
        PW      ! Price index for welfare (expenditure function)

$CONSUMERS:
        CONS    ! Income level for consumer CONS


$PROD:X s:1
        O:PX  Q:100
        I:PL  Q:25   A:CONS T:TX
        I:PK  Q:75   A:CONS T:TX

$PROD:Y s:1
        O:PY  Q:100
        I:PL  Q:75   A:CONS T:TY
        I:PK  Q:25   A:CONS T:TY

$PROD:W s:1
        O:PW   Q:200
        I:PX   Q:100
        I:PY   Q:100

$DEMAND:CONS
        D:PW   Q:200
        E:PL   Q:(100*LENDOW)
        E:PK   Q:(100*KENDOW)

$OFFTEXT

$SYSINCLUDE mpsgeset M10_2

PW.FX = 1;

$INCLUDE M10_2.GEN
SOLVE M10_2 USING MCP;

*       Solve the counterfactuals

TX = 0.5;

$INCLUDE M10_2.GEN
SOLVE M10_2 USING MCP;

TX = 0.5;
TY = 0.5;

$INCLUDE M10_2.GEN
SOLVE M10_2 USING MCP;

TX = 0;
TY = 0;
LENDOW = 2;

$INCLUDE M10_2.GEN
SOLVE M10_2 USING MCP;

LENDOW = 2;
KENDOW = 2;

$INCLUDE M10_2.GEN
SOLVE M10_2 USING MCP;