$TITLE Model M6-1: 2x2 (two goods, two factors) benchmark taxes
*  Positive tax in the X sector in the benchmark

$ONTEXT
                Production Sectors          Consumers

   Markets   |    X       Y        W    |       CONS
   ------------------------------------------------------
        PX   |  100             -100    |
        PY   |          100     -100    |
        PW   |                   200    |       -200
        PL   |  -20     -60             |         80
        PK   |  -60     -40             |        100
        TAX  |  -20       0             |         20
   ------------------------------------------------------

Assume that this is a 100% tax on labor in X: TLX = 1.
Let the CONSUMER price (wage) of labor equal 1: PL = 1.
The PRODUCER price (cost) of labor in X is equal to 2:
   PL*(1+TLX) = 2

$OFFTEXT

SCALAR  TX      Proportional output tax on sector X,
        TY      Proportional output tax on sector Y,
        TLX     Ad-valorem tax on labor inputs to X,
        TKX     Ad-valorem tax on capital inputs to X
        TAXREV  Total tax revenue from all sources;

POSITIVE VARIABLES

        X       Activity level for sector X
        Y       Activity level for sector Y
        W       Activity level for sector W
        PX      Price index for commodity X
        PY      Price index for commodity Y
        PL      Price index for primary factor L
        PK      Price index for primary factor K
        PW      Price index for welfare (expenditure function)
        CONS    Income definition for CONS
        PPLX    Producer price for L in X
        PPKX    Producer price for K in X
        PPX     Producer price for X
        PPY     Producer price for Y;

EQUATIONS

        PRF_X   Zero profit for sector X
        PRF_Y   Zero profit for sector Y
        PRF_W   Zero profit for sector W

        MKT_X   Supply-demand balance for commodity X
        MKT_Y   Supply-demand balance for commodity Y
        MKT_L   Supply-demand balance for primary factor L
        MKT_K   Supply-demand balance for primary factor L
        MKT_W   Supply-demand balance for aggregate demand

        I_CONS  Income definition for CONS

        RPPLX   Relation between consumer and producer price L in X
        RPPKX   Relation between consumer and producer price K in X
        RPPX    Relationship between producer and consumer price of X
        RPPY    Relationship between producer and consumer price of Y;

*       Zero profit conditions:

PRF_X..  100*(PPLX/2)**0.4 * (PPKX)**0.6 =G= 100*PPX;

PRF_Y..  100*PL**0.6 * PK**0.4 =G= 100*PPY;

PRF_W..  200*PX**0.5 * PY**0.5 =G= 200*PW;

*       Market clearing conditions:

MKT_X..  100*X =G= 100*W*PW/PX;

MKT_Y..  100*Y =G= 100*W*PW/PY;

MKT_W..  200*W =G= CONS/PW;

MKT_L..  80  =G= 20*X*PPX/(PPLX/2) + 60*Y*PPY/PL;

MKT_K..  100 =G= 60*X*PPX/PPKX     + 40*Y*PPY/PK;

*       Income constraints:

I_CONS.. CONS =E= 80*PL + 100*PK +  100*PX*X*TX + 100*PY*Y*TY +
                 TLX*PL*20*X* PPX /(PPLX/2) +
                 TKX*PK*60*X* PPX /(PPKX);

RPPLX..  PPLX =E= PL*(1+TLX);
RPPKX..  PPKX =E= PK*(1+TKX);
RPPX..   PPX  =E= PX*(1-TX);
RPPY..   PPY  =E= PY*(1-TY);

MODEL BENCHTAX /PRF_X.X, PRF_Y.Y, PRF_W.W,
                 MKT_X.PX, MKT_Y.PY, MKT_L.PL, MKT_K.PK,
                 MKT_W.PW, I_CONS.CONS,
                 RPPLX.PPLX, RPPKX.PPKX,RPPX.PPX, RPPY.PPY /;

X.L     =1;
Y.L     =1;
W.L     =1;

PL.L    =1;
PX.L    =1;
PY.L    =1;
PK.L    =1;
PW.FX   =1;
PPLX.L  = 2;
PPKX.L  = 1;
PPX.L   = 1;
PPY.L   = 1;

CONS.L  =200;

TX      =0;
TY      =0;
TLX     =1;
TKX     =0;

BENCHTAX.ITERLIM = 0;
SOLVE BENCHTAX USING MCP;

BENCHTAX.ITERLIM = 1000;
SOLVE BENCHTAX USING MCP;

TAXREV = 100*PX.L*X.L*TX + 100*PY.L*Y.L*TY +
          TLX*PL.L*20*X.L* PPX.L /(PPLX.L/2) +
          TKX*PK.L*60*X.L* PPX.L /(PPKX.L);
DISPLAY TAXREV;

*   In the first counterfactual, we replace the tax on
*   labor inputs by a uniform tax on both factors:

TLX = 0.25;
TKX = 0.25;
TX  = 0;
TY  = 0;

SOLVE BENCHTAX USING MCP;

TAXREV = 100*PX.L*X.L*TX + 100*PY.L*Y.L*TY +
          TLX*PL.L*20*X.L* PPX.L /(PPLX.L/2) +
          TKX*PK.L*60*X.L* PPX.L /(PPKX.L);
DISPLAY TAXREV;

*    Now demonstrate that a 25% tax on all inputs
*    is equivalent to a
*    20% tax on the output (or all outputs if more than one)

TLX = 0;
TKX = 0;
TX  = 0.2;
TY  = 0;

SOLVE BENCHTAX USING MCP;

TAXREV = 100*PX.L*X.L*TX + 100*PY.L*Y.L*TY +
          TLX*PL.L*20*X.L* PPX.L /(PPLX.L/2) +
          TKX*PK.L*60*X.L* PPX.L /(PPKX.L);
DISPLAY TAXREV;

*    Demonstrate that a 20% tax on the X sector output is
*    equivalent to a 25% subsidy on Y sector output
*    (assumes that the funds for the subsidy can be raised
*    lump sum from the consumer!)

TKX = 0;
TLX = 0;
TX = 0;
TY = -0.25;

SOLVE BENCHTAX USING MCP;
TAXREV = 100*PX.L*X.L*TX + 100*PY.L*Y.L*TY +
          TLX*PL.L*20*X.L* PPX.L /(PPLX.L/2) +
          TKX*PK.L*60*X.L* PPX.L /(PPKX.L);
DISPLAY TAXREV;

*    Show welfare under non-distortionary taxation

TX = 0.20;
TY = 0.20;

SOLVE BENCHTAX USING MCP;
TAXREV = 100*PX.L*X.L*TX + 100*PY.L*Y.L*TY +
          TLX*PL.L*20*X.L* PPX.L /(PPLX.L/2) +
          TKX*PK.L*60*X.L* PPX.L /(PPKX.L);
DISPLAY TAXREV;

TX = 0.0;
TY = 0.0;

SOLVE BENCHTAX USING MCP;
TAXREV = 100*PX.L*X.L*TX + 100*PY.L*Y.L*TY +
          TLX*PL.L*20*X.L* PPX.L /(PPLX.L/2) +
          TKX*PK.L*60*X.L* PPX.L /(PPKX.L);
DISPLAY TAXREV;