$TITLE  M6-2a.GMS: 2x2 Economy with labor supply and income tax

$ONTEXT
                  Production Sectors                 Consumers

   Markets   |    X       Y        W      TL   TK      CONS
   ----------------------------------------------------------
        PX   |  120             -120
        PY   |          120     -120
        PW   |                   340                  -340
        PLS  |  -48     -72              120
        PKS  |  -72     -48                      120
        PL   |                  -100     -80           180
        PK   |                                   -80    80
        TAX  |                           -40     -40    80
   ----------------------------------------------------------
$OFFTEXT

SETS S /1*6/;

PARAMETERS
  TXL         Labor income tax rate,
  TXK         Capital income tax rate,
  WELFARE(S)  Welfare,
  LABSUP(S)   Labor supply
  INCOME(S)   Money income = consumption of X and Y
  CAPTAX(S)   The level of the capital tax
  TAXREV(S)   Tax revenue generated;

POSITIVE VARIABLES

        X       Activity level for sector X
        Y       Activity level for sector Y
        TL      Supply activity for L
        TK      Supply activity for K
        W       Activity level for sector W

        PX      Price index for commodity X
        PY      Price index for commodity Y
        PL      Price index for primary factor L net of tax
        PK      Price index for primary factor K net of tax
        PLS     Price index for primary factor L gross of tax
        PKS     Price index for primary factor K gross of tax
        PW      Price index for welfare (expenditure function)

        CONS    Income definition for CONS;

EQUATIONS

        PRF_X   Zero profit for sector X
        PRF_Y   Zero profit for sector Y
        PRF_TL  Zero profit for sector TL
        PRF_TK  Zero profit for sector TK
        PRF_W   Zero profit for sector W

        MKT_X   Supply-demand balance for commodity X
        MKT_TK  Supply-demand balance for commodity TK
        MKT_TL  Supply-demand balance for commodity TL
        MKT_Y   Supply-demand balance for commodity Y
        MKT_L   Supply-demand balance for primary factor L
        MKT_K   Supply-demand balance for primary factor K
        MKT_W   Supply-demand balance for aggregate demand

        I_CONS  Income definition for CONS;

*       Zero profit conditions:

PRF_X..  80*PLS**0.4 * PKS**0.6 =G= 120*PX;

PRF_Y..  80*PLS**0.6 * PKS**0.4 =G= 120*PY;

PRF_TL.. 80*PL*(1+TXL) =G= 80*PLS;

PRF_TK.. 80*PK*(1+TXK) =G= 80*PKS;

PRF_W.. 340*(PX)**(12/34) * (PY)**(12/34) * PL**(10/34)
             =G= 340 * PW;

*       Market clearing conditions:

MKT_X..  120*X =G= 340*W*PW * (12/34)/PX;

MKT_Y..  120*Y =G= 340*W*PW * (12/34)/PY;

MKT_W..  340*W =G= CONS / PW;

MKT_L..  180  =G=  80*TL + 340*W*(10/34)*(PW/PL);

MKT_K..  80   =G=  80*TK;

MKT_TL.. 80*TL =G= 48*X*PX/PLS + 72*Y*PY/PLS;

MKT_TK.. 80*TK =G= 72*Y*PY/PKS + 48*X*PX/PKS;

*       Income constraints:

I_CONS.. CONS =E= 180*PL + 80*PK + 80*TL*TXL*PL + 80*TK*TXK*PK;

MODEL INCOMETAX /PRF_X.X, PRF_Y.Y, PRF_TK.TK,PRF_TL.TL,
                 PRF_W.W, MKT_X.PX, MKT_Y.PY, MKT_L.PL,
                 MKT_TK.PKS, MKT_TL.PLS,
                 MKT_K.PK, MKT_W.PW, I_CONS.CONS /;

X.L     =1;
Y.L     =1;
TK.L    =1;
TL.L    =1;
W.L     =1;

PL.L    =1;
PX.L    =1;
PY.L    =1;
PLS.L   =1.5;
PKS.L   =1.5;
PK.L    =1;
PW.FX   =1;
CONS.L  =340;

TXL     =0.5;
TXK     =0.5;

INCOMETAX.ITERLIM = 0;
SOLVE INCOMETAX USING MCP;

*       Lets do some counter-factual with taxes shifted to the
*       factor which is in fixed supply:

INCOMETAX.ITERLIM = 1000;
SOLVE INCOMETAX USING MCP;

LOOP(S,

TXL = 0.60 - 0.10*ORD(S);
TXK = 0.40 + 0.10*ORD(S);

SOLVE INCOMETAX USING MCP;

WELFARE(S) = W.L;
LABSUP(S) = TL.L;
INCOME(S) = ((PX.L/1.5)*X.L + (PY.L/1.5)*Y.L)
           /((PX.L/1.5)**0.5*(PY.L/1.5)**0.5)/2;
CAPTAX(S) = TXK;
TAXREV(S) = (TXL*PL.L*TL.L*80 + TXK*PK.L*TK.L*80)
           /((PX.L/1.5)**0.5*(PY.L/1.5)**0.5);

);

DISPLAY WELFARE, LABSUP, INCOME, CAPTAX, TAXREV;

PARAMETER
 RESULTS(S, *);

RESULTS(S, "WELFARE") = WELFARE(S);
RESULTS(S, "LABSUP") = LABSUP(S);
RESULTS(S, "TAXREV") = TAXREV(S);

DISPLAY RESULTS;


TXL = 0;
TXK = 0;

SOLVE INCOMETAX USING MCP;