$TITLE  Model M24: Closed Economy 2x2 with Specific Factors

$ONTEXT

Here is the initial data matrix for example M21 (also M1_MPS).  As noted
in the text description, it is technically useful to interpret a portion
of capital in each sector as sector specific.  Or it can in fact be a 
separate factor such as land or resources.

                  Production Sectors          Consumers
   Markets   |    X       Y        W    |       CONS
   ------------------------------------------------------
        PX   |  100             -100    |
        PY   |          100     -100    |
        PW   |                   200    |       -200
        PL   |  -25     -75             |        100
        PK   |  -75     -25             |        100
   ------------------------------------------------------

Designate part of the capital in each sector as fixed in that sector

                   Production Sectors          Consumers
    Markets   |    X       Y        W    |       CONS
    ------------------------------------------------------
         PX   |  100             -100    |
         PY   |          100     -100    |
         PW   |                   200    |       -200
         PL   |  -25     -75             |        100
         PK   |  -50     -15             |         65
         PKX  |  -25                     |         25
         PKY  |          -10             |         10
    ------------------------------------------------------

$OFFTEXT

PARAMETERS
 TX;

TX = 0;

$ONTEXT
$MODEL:M24

$SECTORS:
        X       ! Activity level for sector X
        Y       ! Activity level for sector Y
        W       ! Activity level for sector W (Hicksian welfare index)

$COMMODITIES:
        PW      ! Price index for welfare (expenditure function)
        PX      ! Price index for commodity X
        PY      ! Price index for commodity Y
        PL      ! Price index for primary factor L
        PK      ! Price index for (mobile) capital
        PKX     ! Price index for sector-specific input for sector X
        PKY     ! Price index for sector-specific input for sector Y

$CONSUMERS:
        CONS    ! Income level for consumer CONS

$PROD:X s:1
        O:PX   Q:100
        I:PL   Q: 25  A:CONS T:TX
        I:PK   Q: 50  A:CONS T:TX
        I:PKX  Q: 25  A:CONS T:TX

$PROD:Y s:1
        O:PY   Q:100
        I:PL   Q: 75
        I:PK   Q: 15
        I:PKY  Q: 10

$PROD:W s:1
        O:PW   Q:200
        I:PX   Q:100
        I:PY   Q:100

$DEMAND:CONS
        D:PW  Q:200
        E:PL  Q:100
        E:PK  Q:65
        E:PKX Q:25
        E:PKY Q:10

$OFFTEXT
$SYSINCLUDE mpsgeset M24

$INCLUDE M24.GEN
SOLVE M24 USING MCP;

*       Solve a counterfactual:

TX = 0.5;
$INCLUDE M24.GEN
SOLVE M24 USING MCP;