$TITLE  Model M29: Closed 2x2 Economy --  Stone Geary (LES) Preferences

$ONTEXT

The observed data is:

                  Production Sectors          Consumers
   Markets   |    X       Y        W    |       CONS
   ------------------------------------------------------
        PX   |  100             -100    |
        PY   |          100     -100    |
        PW   |                   200    |       -200
        PL   |  -40     -60             |        100
        PK   |  -60     -40             |        100
   ------------------------------------------------------

But calibrated to the model as:

                  Production Sectors          Consumers
   Markets   |    X       Y        W    |       CONS
   ------------------------------------------------------
        PX   |  100              -60    |        -40
        PY   |          100     -100    |
        PW   |                   160    |       -160
        PL   |  -40     -60             |        100
        PK   |  -60     -40             |        100
   ------------------------------------------------------


$OFFTEXT

PARAMETERS
 ENDOW;

ENDOW = 1;

$ONTEXT

$MODEL:M29

$SECTORS:
        X       ! Activity level for sector X
        Y       ! Activity level for sector Y
        W       ! Activity level for sector W (Hicksian welfare index)

$COMMODITIES:
        PX      ! Price index for commodity X
        PY      ! Price index for commodity Y
        PL      ! Price index for primary factor L
        PK      ! Price index for primary factor K
        PW      ! Price index for welfare (expenditure function)

$CONSUMERS:
        CONS    ! Income level for consumer CONS

$PROD:X s:1
        O:PX    Q:100
        I:PL    Q: 40
        I:PK    Q: 60

$PROD:Y s:1
        O:PY    Q:100
        I:PL    Q: 60
        I:PK    Q: 40

$PROD:W s:1
        O:PW    Q:160
        I:PX    Q: 60
        I:PY    Q:100

$DEMAND:CONS
        D:PW    Q:160
        E:PL    Q:(100*ENDOW)
        E:PK    Q:(100*ENDOW)
        E:PX    Q:-40

$OFFTEXT
$SYSINCLUDE mpsgeset M29

PW.FX = 1;

$INCLUDE M29.GEN
SOLVE M29 USING MCP;


*       Counterfactual: double the factor endowment.

ENDOW = 2;

$INCLUDE M29.GEN
SOLVE M29 USING MCP;